From: Bruno Haible <bruno@clisp.org>
Date: Wed, 14 Mar 2012 01:40:49 +0000 (+0100)
Subject: remainderl: Bypass broken implementation in OpenBSD 5.1/SPARC.
X-Git-Tag: v0.1~826
X-Git-Url: http://erislabs.org.uk/gitweb/?a=commitdiff_plain;h=77d42cc5aacc731bd4068de41ee73c716b6dd01c;p=gnulib.git

remainderl: Bypass broken implementation in OpenBSD 5.1/SPARC.

* m4/remainderl.m4 (gl_FUNC_REMAINDERL_WORKS): New macro.
(gl_FUNC_REMAINDERL): Invoke it. If the function does not work, set
REPLACE_REMAINDERL to 1.
* doc/posix-functions/remainderl.texi: Mention the OpenBSD 5.1/SPARC
bug.
---

diff --git a/ChangeLog b/ChangeLog
index 2555d9ed1..f1c464f02 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,14 @@
 2012-03-13  Bruno Haible  <bruno@clisp.org>
 
+	remainderl: Bypass broken implementation in OpenBSD 5.1/SPARC.
+	* m4/remainderl.m4 (gl_FUNC_REMAINDERL_WORKS): New macro.
+	(gl_FUNC_REMAINDERL): Invoke it. If the function does not work, set
+	REPLACE_REMAINDERL to 1.
+	* doc/posix-functions/remainderl.texi: Mention the OpenBSD 5.1/SPARC
+	bug.
+
+2012-03-13  Bruno Haible  <bruno@clisp.org>
+
 	sqrtl: Bypass broken implementation in OpenBSD 5.1/SPARC.
 	* lib/math.in.h (sqrtl): Replace it if REPLACE_SQRTL is 1.
 	* m4/sqrtl.m4 (gl_FUNC_SQRTL_WORKS): New macro.
diff --git a/doc/posix-functions/remainderl.texi b/doc/posix-functions/remainderl.texi
index c6d8aed39..4ec80ef93 100644
--- a/doc/posix-functions/remainderl.texi
+++ b/doc/posix-functions/remainderl.texi
@@ -14,6 +14,9 @@ FreeBSD 6.0, NetBSD 5.0, OpenBSD 3.8, Minix 3.1.8, AIX 5.1, HP-UX 11, older IRIX
 @item
 This function is not declared on some platforms:
 IRIX 6.5.
+@item
+This function returns completely wrong values on some platforms:
+OpenBSD 5.1/SPARC.
 @end itemize
 
 Portability problems fixed by Gnulib module @code{remainderl-ieee}:
diff --git a/m4/remainderl.m4 b/m4/remainderl.m4
index 7c3c2052c..b40464a83 100644
--- a/m4/remainderl.m4
+++ b/m4/remainderl.m4
@@ -1,4 +1,4 @@
-# remainderl.m4 serial 5
+# remainderl.m4 serial 6
 dnl Copyright (C) 2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -47,6 +47,16 @@ AC_DEFUN([gl_FUNC_REMAINDERL],
     dnl Also check whether it's declared.
     dnl IRIX 6.5 has remainderl() in libm but doesn't declare it in <math.h>.
     AC_CHECK_DECLS([remainderl], , [HAVE_DECL_REMAINDERL=0], [[#include <math.h>]])
+
+    save_LIBS="$LIBS"
+    LIBS="$LIBS $REMAINDERL_LIBM"
+    gl_FUNC_REMAINDERL_WORKS
+    LIBS="$save_LIBS"
+    case "$gl_cv_func_remainderl_works" in
+      *yes) ;;
+      *) REPLACE_REMAINDERL=1 ;;
+    esac
+
     m4_ifdef([gl_FUNC_REMAINDERL_IEEE], [
       if test $gl_remainderl_required = ieee && test $REPLACE_REMAINDERL = 0; then
         AC_CACHE_CHECK([whether remainderl works according to ISO C 99 with IEC 60559],
@@ -129,3 +139,46 @@ int main (int argc, char *argv[])
   fi
   AC_SUBST([REMAINDERL_LIBM])
 ])
+
+dnl Test whether remainderl() works.
+dnl It produces completely wrong values on OpenBSD 5.1/SPARC.
+AC_DEFUN([gl_FUNC_REMAINDERL_WORKS],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+  AC_CACHE_CHECK([whether remainderl works], [gl_cv_func_remainderl_works],
+    [
+      AC_RUN_IFELSE(
+        [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+extern
+#ifdef __cplusplus
+"C"
+#endif
+long double remainderl (long double, long double);
+volatile long double x;
+volatile long double y;
+long double z;
+int main ()
+{
+  /* This test fails on OpenBSD 5.1/SPARC.  */
+  x = 9.245907126L;
+  y = 3.141592654L;
+  z = remainderl (x, y);
+  if (z >= 0.0L)
+    return 1;
+  return 0;
+}
+]])],
+        [gl_cv_func_remainderl_works=yes],
+        [gl_cv_func_remainderl_works=no],
+        [case "$host_os" in
+           openbsd*) gl_cv_func_remainderl_works="guessing no";;
+           *)        gl_cv_func_remainderl_works="guessing yes";;
+         esac
+        ])
+    ])
+])