New module 'fpieee'.

diff --git a/ChangeLog b/ChangeLog
index ecb4bfe..4ca6de2 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,13 @@
 2007-03-25  Bruno Haible  <bruno@clisp.org>
 
+       * modules/fpieee: New file.
+       * m4/fpieee.m4: New file.
+       * modules/isnan-nolibm (Depends-on): Add fpieee.
+       * modules/isnanl-nolibm (Depends-on): Add fpieee.
+       * modules/isnanl (Depends-on): Add fpieee.
+
+2007-03-25  Bruno Haible  <bruno@clisp.org>
+
        * m4/frexpl.m4 (gl_FUNC_FREXPL_WORKS): Test also finite numbers.
 
 2007-03-25  Bruno Haible  <bruno@clisp.org>

diff --git a/m4/fpieee.m4 b/m4/fpieee.m4
new file mode 100644 (file)
index 0000000..fd897b0
--- /dev/null
+++ b/m4/fpieee.m4
@@ -0,0 +1,45 @@
+# fpieee.m4 serial 1
+dnl Copyright (C) 2007 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl IEEE 754 standardized three items:
+dnl - The formats of single-float and double-float - nowadays commonly
+dnl   available as 'float' and 'double' in C and C++.
+dnl   No autoconf test needed.
+dnl - The overflow and division by zero behaviour: The result are values
+dnl   '±Inf' and 'NaN', rather than exceptions as it was before.
+dnl   This file provides an autoconf macro for ensuring this behaviour of
+dnl   floating-point operations.
+dnl - A set of conditions (overflow, underflow, inexact, etc.) which can
+dnl   be configured to trigger an exception.
+dnl   This cannot be done in a portable way: it depends on the compiler,
+dnl   libc, kernel, and CPU.  No autoconf macro is provided for this.
+
+dnl Ensure non-trapping behaviour of floating-point overflow and
+dnl floating-point division by zero.
+dnl (For integer overflow, see gcc's -ftrapv option; for integer division by
+dnl zero, see the autoconf macro in intdiv0.m4.)
+
+AC_DEFUN([gl_FP_IEEE],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_REQUIRE([AC_CANONICAL_HOST])
+  # IEEE behaviour is the default on all CPUs except Alpha
+  # (according to the test results of Bruno Haible's ieeefp/fenv_default.m4).
+  case "$host_cpu" in
+    alpha*)
+      # On Alpha systems, a compiler option provides the behaviour.
+      # See the ieee(3) manual page, also available at
+      # <http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/0600____.HTM>
+      if test -n "$GCC"; then
+        # GCC has the option -mieee.
+        CPPFLAGS="$CPPFLAGS -mieee"
+      else
+        # Compaq (ex-DEC) C has the option -ieee. 
+        CPPFLAGS="$CPPFLAGS -mieee"
+      fi
+      ;;
+  esac
+])

diff --git a/modules/fpieee b/modules/fpieee
new file mode 100644 (file)
index 0000000..174627a
--- /dev/null
+++ b/modules/fpieee
@@ -0,0 +1,23 @@
+Description:
+Ensure IEEE compliant floating-point operations (overflow and division by zero).
+
+Files:
+m4/fpieee.m4
+
+Depends-on:
+
+configure.ac-early:
+AC_REQUIRE([gl_FP_IEEE])
+
+configure.ac:
+
+Makefile.am:
+
+Include:
+
+License:
+LGPL
+
+Maintainer:
+Bruno Haible
+

diff --git a/modules/isnan-nolibm b/modules/isnan-nolibm
index 43adb60..101dd94 100644 (file)
--- a/modules/isnan-nolibm
+++ b/modules/isnan-nolibm
@@ -8,6 +8,7 @@ lib/float+.h
 m4/isnan.m4
 
 Depends-on:
+fpieee
 
 configure.ac:
 gl_FUNC_ISNAN_NO_LIBM

diff --git a/modules/isnanl b/modules/isnanl
index 7e60555..c3f768a 100644 (file)
--- a/modules/isnanl
+++ b/modules/isnanl
@@ -10,6 +10,7 @@ m4/isnanl.m4
 m4/longdouble.m4
 
 Depends-on:
+fpieee
 
 configure.ac:
 gl_FUNC_ISNANL

diff --git a/modules/isnanl-nolibm b/modules/isnanl-nolibm
index d45825a..9da825c 100644 (file)
--- a/modules/isnanl-nolibm
+++ b/modules/isnanl-nolibm
@@ -10,6 +10,7 @@ m4/isnanl.m4
 m4/longdouble.m4
 
 Depends-on:
+fpieee
 
 configure.ac:
 gl_FUNC_ISNANL_NO_LIBM