Ensure AC_TYPE_LONG_LONG_INT and AC_TYPE_UNSIGNED_LONG_LONG_INT are consistent.

diff --git a/ChangeLog b/ChangeLog
index aabcdee..8b2c5f1 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,17 @@
+2007-10-31  Bruno Haible  <bruno@clisp.org>
+
+       * m4/longlong.m4 (_AC_TYPE_LONG_LONG_SNIPPET): New macro, extracted
+       from AC_TYPE_LONG_LONG_INT and AC_TYPE_UNSIGNED_LONG_LONG_INT.
+       (AC_TYPE_LONG_LONG_INT): Use it.
+       (AC_TYPE_UNSIGNED_LONG_LONG_INT): Moved here from m4/ulonglong.m4. Use
+       it as well.
+       * m4/ulonglong.m4 (AC_TYPE_UNSIGNED_LONG_LONG_INT): Remove macro; moved
+       to m4/longlong.m4.
+       * modules/stdint (Files): Remove m4/ulonglong.m4.
+       * modules/strtoull (Files): Use m4/longlong.m4 instead of
+       m4/ulonglong.m4.
+       * modules/strtoumax (Files): Likewise.
+
 2007-10-30  Bruno Haible  <bruno@clisp.org>
 
        * modules/xvasprintf-posix: New file.

diff --git a/m4/longlong.m4 b/m4/longlong.m4
index 5799c39..15dc21b 100644 (file)
--- a/m4/longlong.m4
+++ b/m4/longlong.m4
@@ -1,4 +1,4 @@
-# longlong.m4 serial 11
+# longlong.m4 serial 12
 dnl Copyright (C) 1999-2007 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -18,23 +18,11 @@ AC_DEFUN([AC_TYPE_LONG_LONG_INT],
 [
   AC_CACHE_CHECK([for long long int], [ac_cv_type_long_long_int],
     [AC_LINK_IFELSE(
-       [AC_LANG_PROGRAM(
-         [[#if ! (-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
-             error in preprocessor;
-           #endif
-           long long int ll = 9223372036854775807ll;
-           long long int nll = -9223372036854775807LL;
-           typedef int a[((-9223372036854775807LL < 0
-                           && 0 < 9223372036854775807ll)
-                          ? 1 : -1)];
-           int i = 63;]],
-         [[long long int llmax = 9223372036854775807ll;
-           return ((ll << 63) | (ll >> 63) | (ll < i) | (ll > i)
-                   | (llmax / ll) | (llmax % ll));]])],
+       [_AC_TYPE_LONG_LONG_SNIPPET],
        [dnl This catches a bug in Tandem NonStop Kernel (OSS) cc -O circa 2004.
        dnl If cross compiling, assume the bug isn't important, since
        dnl nobody cross compiles for this platform as far as we know.
-        AC_RUN_IFELSE(
+       AC_RUN_IFELSE(
          [AC_LANG_PROGRAM(
             [[@%:@include <limits.h>
               @%:@ifndef LLONG_MAX
@@ -63,6 +51,63 @@ AC_DEFUN([AC_TYPE_LONG_LONG_INT],
   fi
 ])
 
+# Define HAVE_UNSIGNED_LONG_LONG_INT if 'unsigned long long int' works.
+# This fixes a bug in Autoconf 2.61, but can be removed once we
+# assume 2.62 everywhere.
+
+# Note: If the type 'unsigned long long int' exists but is only 32 bits
+# large (as on some very old compilers), AC_TYPE_UNSIGNED_LONG_LONG_INT
+# will not be defined. In this case you can treat 'unsigned long long int'
+# like 'unsigned long int'.
+
+AC_DEFUN([AC_TYPE_UNSIGNED_LONG_LONG_INT],
+[
+  AC_CACHE_CHECK([for unsigned long long int],
+    [ac_cv_type_unsigned_long_long_int],
+    [AC_LINK_IFELSE(
+       [_AC_TYPE_LONG_LONG_SNIPPET],
+       [ac_cv_type_unsigned_long_long_int=yes],
+       [ac_cv_type_unsigned_long_long_int=no])])
+  if test $ac_cv_type_unsigned_long_long_int = yes; then
+    AC_DEFINE([HAVE_UNSIGNED_LONG_LONG_INT], 1,
+      [Define to 1 if the system has the type `unsigned long long int'.])
+  fi
+])
+
+# Expands to a C program that can be used to test for simultaneous support
+# of 'long long' and 'unsigned long long'. We don't want to say that
+# 'long long' is available if 'unsigned long long' is not, or vice versa,
+# because too many programs rely on the symmetry between signed and unsigned
+# integer types (excluding 'bool').
+AC_DEFUN([_AC_TYPE_LONG_LONG_SNIPPET],
+[
+  AC_LANG_PROGRAM(
+    [[/* Test preprocessor.  */
+      #if ! (-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
+        error in preprocessor;
+      #endif
+      #if ! (18446744073709551615ULL <= -1ull)
+        error in preprocessor;
+      #endif
+      /* Test literals.  */
+      long long int ll = 9223372036854775807ll;
+      long long int nll = -9223372036854775807LL;
+      unsigned long long int ull = 18446744073709551615ULL;
+      /* Test constant expressions.   */
+      typedef int a[((-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
+                    ? 1 : -1)];
+      typedef int b[(18446744073709551615ULL <= (unsigned long long int) -1
+                    ? 1 : -1)];
+      int i = 63;]],
+    [[/* Test availability of runtime routines for shift and division.  */
+      long long int llmax = 9223372036854775807ll;
+      unsigned long long int ullmax = 18446744073709551615ull;
+      return ((ll << 63) | (ll >> 63) | (ll < i) | (ll > i)
+             | (llmax / ll) | (llmax % ll)
+             | (ull << 63) | (ull >> 63) | (ull << i) | (ull >> i)
+             | (ullmax / ull) | (ullmax % ull));]])
+])
+
 # This macro is obsolescent and should go away soon.
 AC_DEFUN([gl_AC_TYPE_LONG_LONG],
 [

diff --git a/m4/ulonglong.m4 b/m4/ulonglong.m4
index 34f06e4..971f409 100644 (file)
--- a/m4/ulonglong.m4
+++ b/m4/ulonglong.m4
@@ -1,44 +1,9 @@
-# ulonglong.m4 serial 8
+# ulonglong.m4 serial 9
 dnl Copyright (C) 1999-2007 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
-dnl From Paul Eggert.
-
-# Define HAVE_UNSIGNED_LONG_LONG_INT if 'unsigned long long int' works.
-# This fixes a bug in Autoconf 2.61, but can be removed once we
-# assume 2.62 everywhere.
-
-# Note: If the type 'unsigned long long int' exists but is only 32 bits
-# large (as on some very old compilers), AC_TYPE_UNSIGNED_LONG_LONG_INT
-# will not be defined. In this case you can treat 'unsigned long long int'
-# like 'unsigned long int'.
-
-AC_DEFUN([AC_TYPE_UNSIGNED_LONG_LONG_INT],
-[
-  AC_CACHE_CHECK([for unsigned long long int],
-    [ac_cv_type_unsigned_long_long_int],
-    [AC_LINK_IFELSE(
-       [AC_LANG_PROGRAM(
-         [[#if ! (18446744073709551615ULL <= -1ull)
-             error in preprocessor;
-           #endif
-           unsigned long long int ull = 18446744073709551615ULL;
-           typedef int a[(18446744073709551615ULL <= (unsigned long long int) -1
-                          ? 1 : -1)];
-          int i = 63;]],
-         [[unsigned long long int ullmax = 18446744073709551615ull;
-           return (ull << 63 | ull >> 63 | ull << i | ull >> i
-                   | ullmax / ull | ullmax % ull);]])],
-       [ac_cv_type_unsigned_long_long_int=yes],
-       [ac_cv_type_unsigned_long_long_int=no])])
-  if test $ac_cv_type_unsigned_long_long_int = yes; then
-    AC_DEFINE([HAVE_UNSIGNED_LONG_LONG_INT], 1,
-      [Define to 1 if the system has the type `unsigned long long int'.])
-  fi
-])
-
 # This macro is obsolescent and should go away soon.
 AC_DEFUN([gl_AC_TYPE_UNSIGNED_LONG_LONG],
 [

diff --git a/modules/stdint b/modules/stdint
index 19435d7..8fd2510 100644 (file)
--- a/modules/stdint
+++ b/modules/stdint
@@ -10,7 +10,6 @@ Files:
 lib/stdint.in.h
 m4/stdint.m4
 m4/longlong.m4
-m4/ulonglong.m4
 
 Depends-on:
 include_next

diff --git a/modules/strtoull b/modules/strtoull
index 9ff6f68..9cf4d7f 100644 (file)
--- a/modules/strtoull
+++ b/modules/strtoull
@@ -3,7 +3,7 @@ strtoull() function: convert string to 'unsigned long long'.
 
 Files:
 lib/strtoull.c
-m4/ulonglong.m4
+m4/longlong.m4
 m4/strtoull.m4
 
 Depends-on:

diff --git a/modules/strtoumax b/modules/strtoumax
index 81d85c1..e886285 100644 (file)
--- a/modules/strtoumax
+++ b/modules/strtoumax
@@ -3,7 +3,7 @@ strtoumax() function: convert string to 'uintmax_t'.
 
 Files:
 lib/strtoumax.c
-m4/ulonglong.m4
+m4/longlong.m4
 m4/strtoumax.m4
 
 Depends-on: